ExcelVBA VarType関数 変数の型を示す値を返します

'■VarType関数サンプル１(データ)
Sub VarType_Sample01()
  Dim var As Variant  'Variant型変数を用意
  'Variant型変数Varが初期化されていない状態
  Debug.Print VarType(var)   '0 = vbEmpty
  
  var = Null  'Variant型変数VarにNullを明示的に代入
  Debug.Print VarType(var)   '1 = vbNull
  
  var = 12
  Debug.Print VarType(var)   '2 = vbInteger
  
  var = 1234567890
  Debug.Print VarType(var)   '3 = vbLong
  
  var = CSng(3.45)
  Debug.Print VarType(var)   '4 = vbSingle
  
  var = 678901234567#
  Debug.Print VarType(var)   '5 = vbDouble
  
  var = CCur(1234.5678)
  Debug.Print VarType(var)   '6 = vbCurrency
  
  var = Now
  Debug.Print VarType(var)   '7 = vbDate
  
  var = "1234.5678"
  Debug.Print VarType(var)   '8 = vbString
  
  var = CVErr(5)
  Debug.Print VarType(var)   '10 = vbError
  
  var = True
  Debug.Print VarType(var)   '11 = vbBoolean
  
  var = CDec(12345.67)
  Debug.Print VarType(var)   '14 = vbDecimal
  
  var = CByte(12)
  Debug.Print VarType(var)   '17 = vbByte
End Sub

'■VarType関数サンプル２(オブジェクト)
Sub VarType_Sample02()
  Dim obj As Object
  'ExcelのWorkbookオブジェクトを設定
  Set obj = ThisWorkbook
  'VarType関数を使用してデータ型を確認
  If VarType(obj) = vbObject Then
    MsgBox "obj はオブジェクト型です。VarType: " & VarType(obj)
  Else
    MsgBox "obj はオブジェクト型ではありません。VarType: " & VarType(obj)
  End If
  Set obj = Nothing 'オブジェクト開放
End Sub

'■VarType関数サンプル３(配列)
Sub VarType_Sample03()
  'Variantの配列
  Dim var As Variant
  var = Array(0, "1", 2)
  Debug.Print VarType(var)  '8204 = 12 + 8192
                '12 = vbVariant ,8192 = 配列
  'Integerの配列
  Dim i(10) As Integer
  Debug.Print VarType(i)    '8194 = 2 + 8192
                '2 = vbInteger ,8192 = 配列
  'Stringの配列
  Dim str(10) As String
  str(0) = "あ"
  Debug.Print VarType(str)  '8200 = 8 + 8192
                '8 = vbString ,8192 = 配列
End Sub