ExcelVBA IsDate関数 日付型に変換可能かを判定する

'■IsDate関数サンプル１（基本的な使用例）
Sub IsDate_Sample01()
'▼日付として認識される列（True）
  Debug.Print IsDate(#3/1/2024#)   '日付リテラル
  Debug.Print IsDate("2024/3/1")   'yyyy/m/d
  Debug.Print IsDate("2024/03/01")   'yyyy/mm/dd
  Debug.Print IsDate("24/3/1")   'yy/m/d
  Debug.Print IsDate("令和6年03月01日")  '和暦元号
  Debug.Print IsDate("R6/3/1")   '和暦元号略式
  Debug.Print IsDate("2024-3-1")   'ハイフン区切り
  Debug.Print IsDate("2024,3,1")   'カンマ区切
  Debug.Print IsDate("２０２４／３／１")   '全角文字
  Debug.Print IsDate("March,01,2024")  '英語型式
  Debug.Print IsDate("2024/03")  '年月のみ
    Debug.Print CDate("2024/03")   '2024/03/01 に変換される
  Debug.Print IsDate("03/01")  '月日のみ
    Debug.Print CDate("03/01")   '2024/03/01 に変換される

'▼日付として認識されない列（False）
  Debug.Print IsDate("2026/2/29")  '存在しない年月日
  Debug.Print IsDate("#3/1/2024#")   '文字列の日付リテラル
  Debug.Print IsDate("西暦2024/3/1")   '西暦の文字入
  Debug.Print IsDate("令和六年三月一日")   '漢数字
  Debug.Print IsDate("2024.3.1")   'ドット区切り
  Debug.Print IsDate("20240301")   '区切り無し
  Debug.Print IsDate("2024")   '年数字のみ
  Debug.Print IsDate("令和6年")  '和暦の年のみ
  Debug.Print IsDate("R06")  '和暦の略年のみ
     
'▼時刻として認識される例（True）
  Debug.Print IsDate("2021/01/21 12:00:00")  '日付+時刻
  Debug.Print IsDate("12:00:00")   '時:分:秒 [:]区切り
  Debug.Print IsDate("12時00分00秒")   '時分秒を表記
  Debug.Print IsDate("12時") '時刻のみ
    Debug.Print CDate("12時")  '12:00:00 に変換される
  
'▼時刻として認識されない例（False）
  Debug.Print IsDate("12;00;00")   '時;分;秒 [;]区切りの時刻
  Debug.Print IsDate("12,00,00")   '時,分,秒 [,]区切りの時刻
End Sub

'■IsDate関数サンプル２（判定結果で処理を分岐）
Sub IsDate_Sample02()
  Dim Istr As String
'▼InputBox への入力値(文字列)を検査する
  Do
    Istr = InputBox("日付を入力してください:")
    If Istr = "" Then Exit Do '空白またはキャンセルで中止
    If IsDate(Istr) Then
      MsgBox """" & Istr & """ は有効な日付として認識できます。" & _
              vbCrLf & "CDate(""" & Istr & """)=" & CDate(Istr), _
              vbInformation
    Else
      MsgBox """" & Istr & """ は有効な日付として認識できません！", _
                  vbCritical
    End If
  Loop
End Sub