Excel VBA テーブル操作TableStyleの設定変更

'【汎用】選択テーブルを範囲に変換する
Sub UnListObj()
    Dim ws As Worksheet
    Dim rng As Range
    Dim lobj As ListObject
    'Application.InputBoxで列を指定できるようにする
    On Error Resume Next
    Set rng = Application.InputBox( _
        Prompt:="対象テーブル内のセルを選択してください", _
        Title:="対象テーブル選択", Type:=8)
    On Error GoTo 0
    If rng Is Nothing Then Exit Sub
    rng.Worksheet.Activate
    'セルがListObjectかを確認してから処理する
    On Error Resume Next
    If rng.ListObject.Name = "" Then
        MsgBox "選択セルはテーブル（ListObject）ではありません。"
    Else
        Set ws = ActiveSheet
        Set lobj = ws.ListObjects(rng.ListObject.Name)
        lobj.Range.ClearFormats 'セル書式をクリアします
        lobj.TableStyle = ""    'スタイルを無地にする
        lobj.UnList             'テーブルを解除する
    End If
    On Error GoTo 0
End Sub

Sub GetTableStyleName()
    Dim tbStyl As TableStyle
    Dim i As Long
    For Each tbStyl In ThisWorkbook.TableStyles
        'Debug.Print tbStyl.Name
        i = i + 1
        Cells(i, 1) = tbStyl.Name 'A列1行目から全て書き出します
    Next
End Sub

'テーブルスタイルのサンプルシートを作成する
Sub MakeTblStyleSampleSheet()
    Dim r As Long, c As Long, i As Long
    Dim sName As String
    Sheets.Add Before:=Sheets(1)
    ActiveSheet.Name = "スタイル見本"
    '5行1列のTableStyleサンプルをヨコに7個タテに12個配置
    i = 1   'スタイル名Index初期値
    For r = 1 To 9  'スタイル配置タテのループ
        For c = 1 To 7  'スタイル配置ヨコのループ
            sName = ActiveWorkbook.TableStyles(i).Name
            'テーブル作成
            With ActiveSheet.ListObjects.Add( _
                SourceType:=xlSrcRange, _
                Source:=Cells(r * 6 - 5, c * 2 - 1).Resize(5, 1), _
                XlListObjectHasHeaders:=xlYes)
                '作成後のオブジェクトに設定
                .TableStyle = sName 'テーブルスタイル設定
                .HeaderRowRange.Value = sName '見出しにテーブルスタイル名代入
            End With
          i = i + 1
          If i > 60 Then Exit For  '60個作成できたら抜ける
        Next
    Next
    '列幅を調整（見本の間は1、見本はオート）
    With Columns("A:N")
      .ColumnWidth = 1  'まず全部１にしちゃう
      .AutoFit          'その後にオートフィットする
    End With
End Sub

'テーブルスタイルを変更するサンプル
Sub TableStyleChangeSample()
    Dim tbStyl As TableStyle
    Dim i As Long
    Dim ws As Worksheet
    Dim rng As Range, tgrng As Range
    Dim lobj As ListObject
    'Application.InputBoxで列を指定できるようにする
    On Error Resume Next
    Set rng = Application.InputBox( _
        Prompt:="対象テーブル内のセルを選択してください", _
        Title:="対象テーブル選択", Type:=8)
    On Error GoTo 0
    If rng Is Nothing Then Exit Sub
    rng.Worksheet.Activate
    'セルがListObjectかを確認してから処理する
    On Error Resume Next
    If rng.ListObject.Name = "" Then
        MsgBox "選択セルはテーブル（ListObject）ではありません。"
    Else
        Set ws = ActiveSheet
        Set lobj = ws.ListObjects(rng.ListObject.Name)
        'スタイル見本のセルを指定できるようにする
        Set tgrng = Application.InputBox( _
            Prompt:="現在のスタイルは" & lobj.TableStyle.Name & "です。" & _
                vbCrLf & "変更したいスタイルを見本から選択してください！", _
            Title:="対象スタイル選択", Type:=8)
        On Error GoTo 0
        If tgrng Is Nothing Then Exit Sub
        tgrng.Worksheet.Activate
        lobj.TableStyle = tgrng.ListObject.TableStyle.Name 'スタイルを変更する
        rng.Worksheet.Activate
    End If
    On Error GoTo 0
End Sub