Excel VBA Functionプロシージャを使ってみよう

'簡単なFunction使用例サンプル
Sub sample()
    Dim arg As Long, rslt As Long
    arg = 9
    rslt = f_sample(arg)
    MsgBox "戻り値の数値は" & rslt
End Sub
'Functionサンプル
Function f_sample(arg As Long) As Long
    f_sample = arg * arg    '9×9＝81
End Function

'Functionプロシージャを呼び出すサンプル
Sub fsample()
    Dim a As Long, b As Long
    MsgBox OptIsmis(10, 5)      '50が返ります
    MsgBox OptIsmis(10)         '20が返ります
    a = 10      '変数に代入
    b = 10      '変数に代入
    MsgBox bValRef(a, b)        '40が返ります
    MsgBox a    '戻り値は10（値渡しなので変数は元のまま）
    MsgBox b    '戻り値は20（参照渡しは変数が変化する）
    MsgBox pArry(10, 20, 30)    '60が返ります
    MsgBox pArry(10, 20)        '30が返ります
    MsgBox OptDefVal(10, 2)     '20が返ります
    MsgBox OptDefVal(10)        '50が返ります
End Sub

'Optional使用例（IsMissing関数で第2引数の省略確認）
Function OptIsmis(arg1 As Long, Optional arg2 As Variant)
    If IsMissing(arg2) Then 'Optionalで第２引数arg2は省略可能
        OptIsmis = arg1 * 2    '結果を代入
    Else
        OptIsmis = arg1 * arg2 '結果を代入
    End If
End Function
'「値渡し」と「参照渡し」の例
Function bValRef(ByVal arg1 As Long, ByRef arg2 As Long)
    arg1 = arg1 * 2     'arg1は値渡し
    arg2 = arg2 * 2     'srg2は参照渡し
    bValRef = arg1 + arg2 '結果を代入
End Function
'ParamArrayの使用例「配列」
Function pArry(ParamArray arg() As Variant)
    Dim rslt As Long, i As Long 'argは省略可能な配列
    For i = 0 To UBound(arg)
        rslt = rslt + arg(i)
    Next i
    pArry = rslt    '結果を代入
End Function
'Optional使用例（第2引数の省略で定数を使うサンプル）
Function OptDefVal(arg1 As Long, Optional arg2 As Long = 5)
    OptDefVal = arg1 * arg2 'arg2が省略された場合の既定値は５
End Function