Excel VBA UserForm オプションボタンの利用方法

'最初（表示前）に実行される
Private Sub UserForm_Initialize()
    'TextBoxをイニシャライズするプロシージャを呼び出す
    Call TextBox_Initialize
    'ComboBoxをイニシャライズするプロシージャを呼び出す
    Call ComboBox_Initialize
    'ComboBoxのItemをセットするプロシージャを呼び出す
    Call cbmBox_ItemSet
    OptB1.Value = True  '初期値は「任意」を選択
    TxtBox0.Value = 0   'SelStartの初期値
    TxtBox1.Value = 44  'SelLengthの初期値
End Sub

'重複をチェックして設定値をワークシートに書き込む
Private Sub cmdSave_Click()
    Dim eRow As Long    '最終行
    Dim i As Long       'ループカウンター用
    Dim rng1 As Range, rng2 As Range 'セル範囲
    Dim strSet As String    'Key文字列（A+B+C+D+E+F+G）
    Dim strName As String   '名称文字列（B列）
    Dim OptName As String   '記号オプション設定
    Dim re As Long
    Call cmdPW_Click    'PW生成する
    With Worksheets("設定値")
        eRow = .Cells(Rows.Count, 2).End(xlUp).Row + 1
        strName = Cmb1.Text & Cmb2.Text
        If strName = "" Then MsgBox "「名称」がありません！": Exit Sub
        Select Case True
            Case OptB1.Value: OptName = OptB1.Caption '任意
            Case OptB2.Value: OptName = OptB2.Caption '指定
            Case OptB3.Value: OptName = OptB3.Caption '禁止
        End Select
        strSet = Cmb1.Text & Cmb2.Text & Cmb3.Text & Cmb4.Text & _
                            TxtBox0.Value & TxtBox1.Value & OptName
        If strSet = "" Then MsgBox "「Key」がありません！": Exit Sub
        Set rng1 = Range(.Cells(2, 5), .Cells(eRow, 5))
        '同じItemが存在するかチェックする
        For i = 1 To rng1.Count
            If rng1(i).Value = strSet Then
                MsgBox "重複データのため登録しませんでした！"
                Exit Sub
            End If
        Next
        'Keyに重複が無かった場合、分類+名称で再チェック
        Set rng1 = Range(.Cells(2, 1), .Cells(eRow, 1))
        Set rng2 = Range(.Cells(2, 2), .Cells(eRow, 2))
        '同じ名称が存在するかチェックする
        For i = 1 To rng1.Count
            If rng1(i).Value & rng2(i).Value = strName Then
                re = MsgBox("同じ名称があります！書き換えますか？", _
                                        vbYesNo + vbExclamation)
                If re = vbYes Then
                    'データを上書きさせるため
                    eRow = i + 1 'eRowにセルの行番号を代入
                Else: Exit Sub
                End If
            End If
        Next
        '指定セルにデータを書き込む（追加は最下部）
        .Cells(eRow, 1).Value = Cmb1.Text
        .Cells(eRow, 2).Value = Cmb2.Text
        .Cells(eRow, 3).Value = Cmb3.Text
        .Cells(eRow, 4).Value = Cmb4.Text
        .Cells(eRow, 5).Value = TxtBox0.Value
        .Cells(eRow, 6).Value = TxtBox1.Value
        .Cells(eRow, 7).Value = OptName
        .Cells(eRow, 8).Value = strSet
    End With
End Sub

'テキスト部の文字列を重複せずにItemに登録
Private Sub Cmb2_Change()
    Dim i As Long       'ループカウンター用
    Dim flg As Boolean  '重複チェック用フラグ
    Dim strSet As String
    Dim eRow As Long
    Dim rng As Range
    strSet = Cmb2.Text
    If strSet = "" Then Exit Sub
    With Worksheets("設定値")
        eRow = .Cells(Rows.Count, 2).End(xlUp).Row
        Set rng = Range(Cells(1, 2), .Cells(eRow, 2)) '2列目
        '同じItemが存在するかチェックする
        For i = 2 To rng.Count
            If rng(i).Value = strSet Then
                flg = True  '存在時はflgをTrueに
                Exit For    'ループを抜ける
            End If
        Next
        If i > rng.Count Then Exit Sub
        'flgがTrueの場合はセットする
        If flg = True Then
            Cmb1.Text = .Cells(i, 1).Value
            Cmb3.Text = .Cells(i, 3).Value
            Cmb4.Text = .Cells(i, 4).Value
            If .Cells(i, 5).Value <> "" Then _
                TxtBox0.Value = .Cells(i, 5).Value
            If .Cells(i, 6).Value <> "" Then
                TxtBox1.Value = .Cells(i, 6).Value
                SpinB1.Value = TxtBox1.Value
            End If
            Select Case .Cells(i, 7).Value
                Case OptB1.Caption: OptB1.Value = True '任意
                Case OptB2.Caption: OptB2.Value = True '指定
                Case OptB3.Caption: OptB3.Value = True '禁止
            End Select
        End If
    End With
    Call cmdPW_Click
    Call SpinB1_Change
End Sub

Private Sub OptB1_Click()
    txtPW.SetFocus   'フォーカスを戻す
End Sub
Private Sub OptB2_Click()
    txtPW.SetFocus   'フォーカスを戻す
End Sub
Private Sub OptB3_Click()
    txtPW.SetFocus   'フォーカスを戻す
End Sub