VBA ListView の表示データと元データを同時に削除する

'マウス右クリック時に選択ListItemを削除する
Private Sub ListView1_MouseDown(ByVal Button As Integer, _
                                ByVal Shift As Integer, _
                                ByVal x As stdole.OLE_XPOS_PIXELS, _
                                ByVal y As stdole.OLE_YPOS_PIXELS)
    Dim res As Long
    If Button = 2 Then 'MouseButton 2 = 右側ボタン"
        With ListView1
            res = MsgBox("現在選択されている " & vbCrLf & _
                "名称:「" & .SelectedItem & "」/分類:「" & _
                .SelectedItem.SubItems(1) & "」" & vbCrLf & _
                "を削除してよろしいですか？", vbYesNo + vbQuestion)
            If res = vbYes Then
                .ListItems.Remove .SelectedItem.Index
            End If
        End With
    End If
End Sub

'マウス右クリック時に選択ListItemを削除する
Private Sub ListView1_MouseDown(ByVal Button As Integer, _
                                ByVal Shift As Integer, _
                                ByVal x As stdole.OLE_XPOS_PIXELS, _
                                ByVal y As stdole.OLE_YPOS_PIXELS)
    Dim res As Long
    Dim strKey As String 'Key文字列保存用
    Dim eRow As Long    '最終行用
    Dim LData As Range  'セル範囲指定用
    If Button = 2 Then 'MouseButton 2 = 右側ボタン"
        With ListView1
            strKey = .SelectedItem.SubItems(7) '【Key】取得
            res = MsgBox("現在選択されている " & vbCrLf & _
                "名称:[" & .SelectedItem & "]/分類:[" & _
                .SelectedItem.SubItems(1) & "]" & vbCrLf & _
                "Key[" & strKey & "]" & vbCrLf & _
                "を削除してよろしいですか？", vbYesNo + vbQuestion)
            If res = vbYes Then
                .ListItems.Remove .SelectedItem.Index
                With Worksheets("設定値")
                    eRow = .Cells(Rows.Count, 8).End(xlUp).Row
                    Set LData = .Range(.Cells(1, 8), .Cells(eRow, 8)) _
                                .Find(What:=strKey) 'Key列内セル文字列を検索
                    If LData Is Nothing Then        '検索該当なしの回避用
                        MsgBox "検索データが不明です！"
                    Else
                        LData.EntireRow.Delete '行全体を削除
                    End If
                End With
            End If
        End With
    End If
End Sub