Excel VBA プログレスバーをラベルに置き換えて表現する

Option Explicit
Public IsCancel As Boolean 'キャンセルボタン用フラグ
Private Sub UserForm_Initialize()
  Caption = "進捗状況"
  'フレームとラベルの位置は同一にする
  With Me.Label1
    .Left = 0
    .Top = 0
    .Width = 0
    .Visible = True
  End With
  'キャンセルフラグにFalseを設定
  IsCancel = False
End Sub
'キャンセルボタンクリックイベント
Private Sub CommandButton1_Click()
  'キャンセルフラグにTrueを設定
  IsCancel = True
End Sub

Option Explicit
'貼付け元シート上で開始すること
'プログレスバーフォームを作成>表示>削除
Sub Array_match()
    Dim workSh As Worksheet, prefSh As Worksheet
    Dim sName As String
    Set prefSh = ThisWorkbook.ActiveSheet
    sName = prefSh.Range("K1").Value    '取得データ貼付け先シート名
    Set workSh = ThisWorkbook.Worksheets(sName)
    Dim ptCol As Long, pFlgCol As Long
    Dim pMCol As Long, pCol() As Long
    Dim wtCol As Long, wFlgCol As Long
    Dim wMCol As Long, wCol() As Long
    Dim pRow As Long, wRow As Long
    Dim i As Long
    
    '▼マーク（ターゲット）列を検索
    ptCol = Application.WorksheetFunction.Match("▼", prefSh.Rows(2), 0)
    wtCol = Application.WorksheetFunction.Match("▼", workSh.Rows(2), 0)
    '設定行の最大数
    pMCol = Application.WorksheetFunction.Max(prefSh.Rows(2))
    wMCol = Application.WorksheetFunction.Max(workSh.Rows(2))
    'データ開始列の設定
    pRow = prefSh.Range("G1")
    wRow = workSh.Range("G1")
    '設定の不整合を判定する処理
    If pMCol <> wMCol Then
        MsgBox "引き当てる列の数が不整合のため中止します！"
        Exit Sub
    End If
    ReDim pCol(1 To pMCol)  '指定列を代入する
    pFlgCol = 0 '指定列の配置が連続しているかどうか調べる「0」は連続
    For i = 1 To pMCol
        pCol(i) = Application.WorksheetFunction.Match(i, prefSh.Rows(2), 0)
        If i > 1 Then
            If pCol(i) <> pCol(i - 1) + 1 Then pFlgCol = 1 '連続していない場合「1」
        End If
    Next
    ReDim wCol(1 To wMCol)  '貼付け先も同様に調べる
    wFlgCol = 0
    For i = 1 To wMCol
        wCol(i) = Application.WorksheetFunction.Match(i, workSh.Rows(2), 0)
        If i > 1 Then
            If wCol(i) <> wCol(i - 1) + 1 Then wFlgCol = 1 '連続していない場合「1」
        End If
    Next
    Dim workShEndR As Long, prefShEndR As Long
    Dim tgetTmpR As Long, tmpStr As Variant '文字列の場合もあるのでVariantで
    '最終行取得
    workShEndR = workSh.Cells(Rows.Count, wtCol).End(xlUp).Row
    prefShEndR = prefSh.Cells(Rows.Count, ptCol).End(xlUp).Row
    Dim tgetRng As Range
    'ターゲット（ID）の列範囲をセット
    Set tgetRng = Range(prefSh.Cells(pRow, ptCol), prefSh.Cells(prefShEndR, ptCol))
    
    'オートフィルタが設定されていたら解除する
    If (workSh.AutoFilterMode = True) Then workSh.Rows(wRow - 1).AutoFilter
    '開始件数チェック
    If IsNumeric(Range("N1").Value) = True Then
        If Range("N1").Value > wRow Then wRow = Range("N1").Value
    End If
    
    Dim matchRng As Variant '行取得用
    Dim MyArray() As Variant '配列用

    '///プログレスバー用///
    Dim lngHcount As Long   'HIT件数カウント用
    Dim percent As Long
    Dim starttime As Single
    Dim myspeed As Single
    Dim strMsg As String    'メッセージ用
    Dim f As Long           'Frame1の幅
    Dim n As Long           'Loopカウンター
    Dim k As Long           '総件数
    
    Call マクロ開始
    
    lngHcount = 0           'ヒットカウント初期化
    starttime = Time        'タイマーセット
    
    With UserForm1
        .Show vbModeless            'Modelessで表示
        f = .Frame1.Width           'フレームの横幅取得
        'ターゲットID件数分のループ
        k = workShEndR - wRow + 1   '最終行-開始行+1
        n = 0                'カウンター初期化
        Do
            If n = k Then Exit Do   '全終了確認したら抜ける
            DoEvents                '途中で中断ができるように
            tgetTmpR = n + wRow
            tmpStr = workSh.Cells(tgetTmpR, wtCol).Value  '検索対象ID
            '発見できなかった場合エラーでマクロが停止するので制御する
            On Error Resume Next
            '対象IDコードを配列から検索
            matchRng = Application.WorksheetFunction.Match(tmpStr, tgetRng, 0)
            If Err <> 0 Then
                matchRng = ""       'ERRORの場合空白に
                Err.Clear
            End If
            If matchRng <> "" Then  '""なら何もしない
                matchRng = matchRng + wRow - 1 '開始行分をプラスする-1
                '配列のメモリ領域割り当て
                ReDim MyArray(1 To pMCol)
                If pFlgCol = 1 Then '不連続の場合ループ、連続の場合一括書込み
                    For i = 1 To pMCol
                        MyArray(i) = prefSh.Cells(matchRng, pCol(i)).Value
                    Next
                Else
                    MyArray() = prefSh.Range(prefSh.Cells(matchRng, pCol(1)), _
                                    prefSh.Cells(matchRng, pCol(pMCol))).Value
                End If
                If wFlgCol = 1 Then '不連続の場合ループ、連続の場合一括書込み
                    For i = 1 To wMCol
                        workSh.Cells(tgetTmpR, wCol(i)).Value = MyArray(i)
                    Next
                Else
                    workSh.Range(workSh.Cells(tgetTmpR, wCol(1)), _
                            workSh.Cells(tgetTmpR, wCol(pMCol))) = MyArray
                End If
                lngHcount = lngHcount + 1   'ヒット数カウントアップ
                Erase MyArray       '配列初期化
            End If
            n = n + 1               '処理数カウントアップ
            '///プログレスバーキャンセルボタン処理///
            If .IsCancel = True Then
                strMsg = "処理を中断しました。"
                Exit Do
            End If
            '//プログレスバーの値表示を更新//
            .Label1.Width = n * f / k   '件×最大Width÷総件数
            '//プログレスバーのLabel2表示を更新//
            percent = CInt(n / k * 100) '進捗率計算
            .Label2.Caption = percent & "%完了【処理件数： " & _
                            n & " / " & k & " 】" & _
                            "【HIT件数：" & lngHcount & "件】"
        Loop
    End With
    
    Call マクロ終了
    
    If n = k Then   '処理完了なら次のメッセージをセット
        myspeed = Time - starttime  '現在時刻－スタート時刻
        strMsg = "処理が完了しました！" & _
            "処理時間は" & Minute(myspeed) & "分" & _
            Second(myspeed) & "秒 でした" & vbCrLf & _
            "【データ更新件数は： " & lngHcount & " 件でした】"
    End If
    MsgBox strMsg, vbInformation, "処理状況メッセージ"
    'プログレスバーFormを閉じる（メッセージ前に閉じてもOK）
    Unload UserForm1
End Sub