ExcelVBA Dir 関数 ファイルやフォルダの名前を返す

'■Dir関数使用例1（単一ファイル検索例）
Sub Dir_Sample01()
    Dim fName As String

    ' 特定のファイルを検索
    fName = Dir("C:\VBA_test\Sample_02.xls")
    
    ' 結果で処理を分岐
    If fName <> "" Then
        MsgBox "ファイル【" & fName & "】が見つかりました！"
    Else
        MsgBox "ファイルは見つかりませんでした。"
    End If
End Sub

'■Dir関数使用例２（複数ファイルの検索例）
Sub Dir_Sample02()
    Dim fName As String
    Dim fList As String       'ファイルリスト用

    ' 特定パターン「*.xls」のファイルを検索
    fName = Dir("C:\VBA_test\*.xls")

    ' 検索結果を表示
    If fName <> "" Then
        fList = "見つかったファイル一覧："
        Do While fName <> ""
            fList = fList & vbCrLf & fName
            fName = Dir()   ' 次のファイルを検索
        Loop
        MsgBox fList        ' 見つかったファイル一覧を表示
    Else
        MsgBox "ファイルは見つかりませんでした。"
    End If
End Sub

'■Dir関数使用例３（フォルダの検索例）
Sub Dir_Sample03()
    Dim fName As String, path As String
    Dim fList As String
    
    ' 検索するパスを指定
    path = "C:\VBA_test\"
    ' パス直下のフォルダを検索
    fName = Dir(path, vbDirectory)
    
    ' 検索結果を表示
    If fName <> "" Then
        fList = "見つかったフォルダ一覧："
        Do While fName <> ""
            ' "." と ".." は除外する
            If fName <> "." And fName <> ".." Then
                ' フォルダかどうかを「GetAttr関数」で確認
                If GetAttr(path & fName) = vbDirectory Then
                    fList = fList & vbCrLf & fName
                End If
            End If
            fName = Dir()     ' 次のフォルダを取得
        Loop
        MsgBox fList     ' 見つかったフォルダ一覧を表示
    Else
        MsgBox "フォルダは見つかりませんでした。"
    End If
End Sub