Excel VBA Date など日付・時刻関数の使用例について

'日付関連関数のテスト
Sub DateFunction_Sample()
    Cells(1, 1) = Date                          'yyyy/mm/dd
    Cells(2, 1) = DateAdd("m", 3, "2020/11/30") '2021/1/31
    Cells(3, 1) = DateDiff("d", "2020/11/30", "2021/1/31") '62
    Cells(4, 1) = DatePart("m", Date)           'mm
    Cells(5, 1) = DateSerial(2021, 1, 12)       '2021/1/12
    Cells(6, 1) = DateValue("2021, 1, 12")      '2021/1/12
    Cells(7, 1) = Day(Date)                     'dd
    Cells(8, 1) = Hour(Now)                     'hh
    Cells(9, 1) = Minute(Now)                   'dd
    Cells(10, 1) = Month(Date)                  'mm
    Cells(11, 1) = MonthName(Month(Date))       'mm月
    Cells(12, 1) = Now                          'yyyy/mm/dd hh:mm
    Cells(13, 1) = Second(Now)                  'ss
    Cells(14, 1) = Time                         'hh:mm:ss
    Cells(15, 1) = Timer                        's.m
    Cells(16, 1) = TimeSerial(8, 30, 0)         '8:30:00
    Cells(17, 1) = TimeValue("12:0:10")         '12:00:10
    Cells(18, 1) = Weekday(Now)                 'w（曜日番号）
    Cells(19, 1) = WeekdayName(Weekday(Now))    'w曜日
    Cells(20, 1) = Year(Now)                    'yyyy
End Sub

'Date関数で取得したデータをFormat関数で成型する
Sub DateFormat_Sample()
    Cells(22, 1) = Format(Date, "yyyy/mm/dd")   'yyyy/mm/dd
    Cells(23, 1) = Format(Date, "yyyy年m月d日")  'yyyy年m月d日
    Cells(23, 1) = Format(Date, "yyyy年mm月dd日")  'yyyy年mm月dd日
    Cells(24, 1) = Format(Date, "ggge/m/d")     '令和e/m/d
    Cells(24, 1) = Format(Date, "ggge/mm/dd")   '令和e/mm/dd
    Cells(25, 1) = Format(Date, "yyyy/mmm/ddd(dddd)") 'yyyy/mmm/ddd(dddd)
    Cells(26, 1) = Format(Date, "ggge/mm/dd(aaaa)")   '令和e/mm/dd(aaaa)
End Sub

'終了時刻と開始時刻の差で経過時間を計算する
Sub 時間計算例_1()
    Dim t1 As Date, t2 As Date
    t1 = TimeValue("9:30:00")
    t2 = TimeValue("15:15:00")
    Cells(1, 15).NumberFormatLocal = "h:mm"     'セル書式を日付に設定
    Cells(1, 15) = t2 - t1                      '結果例：5:45
End Sub

'シリアル値を使った勤務時間計算例
Sub 時間計算例_2()
    Const jikan As Single = 0.041667    '昼休み時間をシリアル値で定数化
    Dim lunch As Single
    Dim t1 As Date, t2 As Date
    Dim msg As String
    t2 = TimeValue("16:00:00")  'TimeValue関数で勤務終了時刻をt2に代入
    msg = "出勤時間を入力して下さい" & Chr(10) _
        & "(例：9：15 又は、13：00 or PM1：00）"
    t1 = InputBox(msg, "出勤時間")      '出勤時刻を入力要求
    If t1 > 0.666666666666667 Then      '入力値が16:00以降の場合抜ける
        MsgBox msg
        Exit Sub
    End If
    '昼休み時間を判定
    If t1 < 0.5 Then    '12:00のシリアル値は0.5
        lunch = jikan   '12:00以前に出勤していればIunchに定数代入
    Else                '12:00～1:00の間に出勤した場合は13:00出社とする
        If (0.5 + jikan) > t1 Then t1 = TimeValue("13:00:00")
    End If
    MsgBox Format(t2 - t1 - lunch, "h:mm") '勤務時間の計算結果を表示
End Sub

'シリアル値を計算した年齢算出例
Sub 時間算出例_3()
Dim msg As String, ymd As Date, Inymd As String
    msg = "生年月日を入力して下さい" & Chr(10) _
            & "yyyy/mm/dd のように/で区切って入力して下さい"
    Inymd = InputBox(msg, "生年月日入力")
    '日付データが入力されたかどうか判定する
    If IsDate(Inymd) = False Then
        MsgBox "入力データは日付に変換できません"
        Exit Sub
    Else
        ymd = DateValue(Inymd) '日付データを件数に代入
        End If
    Call 時間算出例_4(ymd)  '年齢算出プロシージャ呼び出し
End Sub

'年齢計算（うるう年を考慮して年齢算出する例）
Sub 時間算出例_4(DateOfBirth As Date)
    Dim age As Long
    'Int関数でデータを整数にまるめます
    age = Int((Date - DateOfBirth + 1) / 365.25) 'うるう年を考慮して算出
    MsgBox DateOfBirth & "生まれの方の" & Chr(10) & _
    "今現在の年齢は「" & age & "」歳です。"
End Sub