Excel VBA Timer など覚えておきたい日付時刻の処理

Option Explicit
'簡単なタイマー関数使用例
Sub TimerTestSample()
    Dim i As Long, j As Long, k As Long
    Dim n As Double
    Dim sTime As Single '計測開始データ保存用
    
    Columns("B:J").Clear 'データをクリアします
    n = InputBox("処理時間にウエイトをかけます。" & vbCrLf _
                & "数値を入力してください（10で約3秒です）") * 1000000
    
    '測定スタート時のタイマー値を変数に保存する
    sTime = Timer
     
    '計測したい処理を入れる
    For i = 1 To 10
        For j = 2 To 10
            'Rnd関数で単精度浮動小数点型の乱数を発生させています
            Cells(2, j) = Int((55 - 1 + 1) * Rnd + 1)
            Cells(2, j).Interior.ColorIndex = Cells(2, j) 'セルの色変更
            Cells(4, 2) = "処理進捗状況→" & i & "(" & j & "/10)" & "/10"
            '時間調整用
            For k = 1 To n
                '単に時間調整しています
            Next
        Next
    Next
 
    '処理時間を計算してメッセージボックスに表示します
    MsgBox "マクロ処理時間⇒　" & Timer - sTime & "秒"
 
End Sub

'2次元のループを使用する例
Sub WaitSample_01()
    Dim i As Long, j As Long
    For i = 1 To 1000
        For j = 1 To 1000
        Next
    Next
End Sub

'Timer関数を利用する例
Sub WaitSample_02()
    Dim sTime As Single
    
    sTime = Timer + 1   '現在のTimer値+1秒
    Do
        If Timer > sTime Then   '1秒以上経過するまでループ
            Exit Do
        End If
        DoEvents    'これを入れておけば途中キャンセルできる
    Loop
End Sub

'Application.Waitメソッドを使用する例
Sub WaitSample_03()
    '現在時刻+1秒待つ
    Application.Wait (Now + TimeValue("0:00:01"))
End Sub

'文字列置換で日付型に変換する
Sub StrReplaceDate()
    Dim er As Long
    er = Range("A1000").End(xlUp).Row   '最終行取得
    '文字列を置換して日付型に変更する
    With Range(Cells(3, 1), Cells(er, 1))
        .Replace What:="年", Replacement:="/"
        .Replace What:="月", Replacement:="/"
        .Replace What:="日", Replacement:=""
    End With
End Sub

'セル書式を日付型に設定してDateValueで変換
Sub DateFormatValue()
    Dim er As Long, i As Long
    er = Range("A1000").End(xlUp).Row   '最終行取得
    '日付型にセル書式を指定
    Range(Cells(3, 1), Cells(er, 1)).NumberFormatLocal = "yyyy/m/d;@"
    For i = 1 To er
        Cells(i, 1).Value = DateValue(Cells(i, 1).Value)
    Next
End Sub

'Findメソッドで日付を検索する
Sub DateFindSample()
    Dim mydate As Date, tgrn As Range, myrng As Range
    Dim hitadd As String, msg As String, hitr As Long
    Set tgrn = ThisWorkbook.Worksheets("Sheet1").Columns(1)
    mydate = "2021/1/7"
    With tgrn
        'Findメソッドで検索
        Set myrng = .Find(mydate, , , xlWhole)
        If Not myrng Is Nothing Then
            hitadd = myrng.Address
            Do
                hitr = myrng.Row
                msg = msg & hitr & "行目にありました！"
                Set myrng = .FindNext(myrng)
                If myrng.Address = hitadd Then
                    Exit Do
                End If
            Loop
        Else
            msg = "ヒットしませんでした"
        End If
    End With
    MsgBox "[" & mydate & "]データは" & Chr(10) & msg
End Sub

'和暦でオートフィルタ検索
Sub WaDateFilter()
    Dim er As Long
    Dim tgrn As Range
    er = Range("L1000").End(xlUp).Row   '最終行取得
    Set tgrn = Range(Cells(2, 12), Cells(er, 12))
    tgrn.AutoFilter Field:=1, Criteria1:="令和3年1月17日" '文字列で検索
End Sub

'シリアル値日付でフィルタ検索
Sub SerialDateFilter()
    Dim er As Long
    Dim tgrn As Range
    er = Range(L1000").End(xlUp).Row   '最終行取得
    Set tgrn = Range(Cells(2, 12), Cells(er, 12))
    tgrn.AutoFilter Field:=1, Criteria1:=DateValue("令和3年1月17日") 'シリアル値で検索
End Sub