VBA GetAttr 関数 ファイルやフォルダの属性を取得する

'■GetAttr関数使用例1（単一ファイルの属性を確認する例）
Sub GetAttr_Sample01()
    Dim fName As String
    Dim strAttr As String
    Dim i As Integer
    ' 指定ファイルの存在確認は省略しています
    fName = "C:\VBA_test\Sample_02.xls"
    i = GetAttr(fName)
    If i = vbNormal Then
        MsgBox fName & "は標準ファイルです"
    Else
        ' GetAttr関数の戻り値から属性を判断して表示します
        Dim str As String
        Do While i <> 0
            Select Case i
                Case Is >= 32: str = "【アーカイブ】": i = i - 32
                Case Is >= 16: str = "【フォルダ】": i = i - 16
                Case Is >= 4: str = "【システム】": i = i - 4
                Case Is >= 2: str = "【非表示(隠し)】": i = i - 2
                Case Is >= 1: str = "【読み取り専用】": i = i - 1
            End Select
            strAttr = strAttr & str & vbCrLf
        Loop
        MsgBox fName & "は標準ファイルではありません" & _
                        vbCrLf & "以下の属性を持っています" & _
                        vbCrLf & strAttr
    End If
End Sub

'■GetAttr関数使用例２（フォルダ内の一覧を属性付きで表示する例）
Sub GetAttr_Sample02()
  Dim fName As String, path As String
  Dim strAttr As String, fList As String
  Dim i As Integer
  Dim str As String
    
  ' 検索するパスを指定
  path = "C:\VBA_test\"
  ' パス内のファイル・フォルダを検索（隠し属性を含む）
  fName = Dir(path, vbDirectory + vbHidden)
  ' 検索結果に対する処理
  If fName <> "" Then
    fList = "見つかったファイル・フォルダの一覧とその属性："
    '複数の存在を確認
    Do While fName <> ""
      ' "." と ".." は除外する
      If fName <> "." And fName <> ".." Then
        i = GetAttr(path & fName)
        ' GetAttr関数の戻り値から属性を判断して表示します
        If i = 0 Then strAttr = "【標準】"
        Do While i <> 0
            Select Case i
                Case Is >= 32: str = "【アーカイブ】": i = i - 32
                Case Is >= 16: str = "【フォルダ】": i = i - 16
                Case Is >= 4: str = "【システム】": i = i - 4
                Case Is >= 2: str = "【非表示(隠し)】": i = i - 2
                Case Is >= 1: str = "【読み取り専用】": i = i - 1
            End Select
            strAttr = strAttr & str
        Loop
        fList = fList & vbCrLf & fName & "：属性=" & strAttr
        strAttr = ""
      End If
      fName = Dir()     ' 次のファイル・フォルダを取得
    Loop
    MsgBox fList     ' 見つかったファイル・フォルダの一覧を表示
  Else
    MsgBox "ファイル・フォルダは見つかりませんでした。"
  End If
End Sub