ExcelVBA IsArray関数 配列かどうかを判定します

'■IsArray関数サンプル１（各種配列の判定）
Sub IsArray_Sample01()
  Dim b As Boolean  'IsArrayの結果保存用

'1. Variant変数の配列
  Dim variantArray As Variant       'バリアント変数宣言
  '宣言直後初期化前の変数
  b = IsArray(variantArray)   ' False
  Debug.Print "1-1. 初期化前のVariant変数 = " & b
  variantArray = Array(1, 2, 3)     'Array関数で配列代入
  b = IsArray(variantArray)   ' True
  Debug.Print "1-2. 配列を代入したVariant = " & b
  
'2. 静的（固定）配列
  Dim staticArray(7) As Integer     '静的配列の変数宣言
  b = IsArray(staticArray)    ' True
  Debug.Print "2. Integer型の静的配列 = " & b

'3. 動的（変動）配列
  Dim dynamicArray() As Variant   '動的配列の変数宣言
  b = IsArray(dynamicArray)   ' True
  Debug.Print "3-1. 領域割当なしの動的配列 = " & b
  ReDim dynamicArray(15)
  b = IsArray(dynamicArray)   ' True
  Debug.Print "3-2. 領域割当後の動的配列 = " & b

'4. 多次元配列
  Dim multiArray(3, 5) As Integer   '2次元配列の変数宣言
  b = IsArray(multiArray)   ' True
  Debug.Print "4. 多次元（2次元）配列 = " & b

End Sub

'■IsArray関数サンプル２（配列判定後に要素数取得）
Sub IsArray_Sample02()
  Dim vArray As Variant       'バリアント変数宣言
  vArray = Array(1, 2, 3, 4, 5)
  If IsArray(vArray) Then
    MsgBox "配列の要素数は " & _
    UBound(vArray) - LBound(vArray) + 1 & " です。"
  Else
    MsgBox "vArrayは配列ではありません！"
  End If
End Sub