Excelブック内全数式を一括取得・貼り付けするVBA汎用ツール

Option Explicit
'Excelブック内の全数式の設定を取得して書き出す
Sub GetFormulas()
    Dim wb As Workbook
    Dim sh As Worksheet
    Dim rng As Range
    Dim rn As Range
    Dim c As Long, r As Long
    Dim selectFileName As String
    'ファイル選択ダイアログを表示
    selectFileName = _
        Application.GetOpenFilename( _
            FileFilter:="Microsoft Excel ブック,*.xls?", _
            Title:="対象ファイルを選択してください", _
            MultiSelect:=False)
    If selectFileName = "False" Then _
                MsgBox ("未選択のため処理を中止します！"): Exit Sub
    With Application
        .ScreenUpdating = False             '画面描画停止
        .Calculation = xlCalculationManual  '計算を手動に
    End With
    Dim tgwb As Workbook
    'ブックを開きオブジェクト変数に入れる
    Set tgwb = Workbooks.Open(Filename:=selectFileName, UpdateLinks:=0)
    ThisWorkbook.Activate   'アクティブを開いたブックから自ブックに戻す
    Set wb = ThisWorkbook   '自ブックをオブジェクト変数にセット
    With wb.Sheets("Formula")   'ActiveSheetでもいいけどあえて指定してる
        .Cells.Clear            'シートをクリア
        .Cells.NumberFormatLocal = "G/標準" '書式設定を標準にする
        On Error Resume Next    '数式がない場合のエラーを無視する
        For Each sh In tgwb.Sheets  '開いたブック内のシート数分のループ
            If sh.Name = "Formula" Then GoTo pass '"Formula"はパスする
            c = c + 1   '書き込み先の列設定用（最初を１にするため）
            .Cells(1, c) = sh.Name          'シート名書き込み
            .Cells(2, c) = "Range"          'レンジアドレス見出し
            .Cells(2, c + 1) = "Formula"    '数式見出し
            'SpecialCellsで数式セルだけをRangeオブジェクトにセット
            Set rng = sh.Cells.SpecialCells(xlCellTypeFormulas)
            r = 2
            For Each rn In rng
                r = r + 1
                .Cells(r, c) = rn.Address      'セルのRangeアドレス
                .Cells(r, c + 1).NumberFormatLocal = "@" '書式を文字列に
                .Cells(r, c + 1) = rn.Formula  '数式
            Next
            c = c + 1   '書き込み先の列インクリメント用
pass:
        Next
    End With
    tgwb.Close (False)  '開いたブックを閉じる
    Set tgwb = Nothing  'オブジェクト解放
    Set wb = Nothing
    Set sh = Nothing
    With Application
        .Calculation = xlCalculationAutomatic '計算を自動に
        .ScreenUpdating = True                '画面描画開始
    End With
    MsgBox "計算式の取得処理を完了しました！"
End Sub

'保存した数式の設定データを使って再設定する
Sub SetFormulas()
    Dim wb As Workbook
    Dim sh As Worksheet
    Dim rng As String
    Dim n As Long
    Dim c As Long, r As Long, i As Long
    Dim selectFileName As String
    'ファイル選択ダイアログを表示
    selectFileName = _
        Application.GetOpenFilename( _
            FileFilter:="Microsoft Excel ブック,*.xls?", _
            Title:="対象ファイルを選択してください", _
            MultiSelect:=False)
    If selectFileName = "False" Then _
                MsgBox ("未選択のため処理を中止します！"): Exit Sub
    With Application
        .ScreenUpdating = False             '画面描画停止
        .Calculation = xlCalculationManual  '計算を手動に
    End With
    Dim tgwb As Workbook
    'ブックを開きオブジェクト変数に入れる
    Set tgwb = Workbooks.Open(Filename:=selectFileName, UpdateLinks:=0)
    ThisWorkbook.Activate   'アクティブを開いたブックから自ブックに戻す
    Set wb = ThisWorkbook   '自ブックをオブジェクト変数にセット
    With wb.Sheets("Formula")
        On Error Resume Next
        For Each sh In tgwb.Sheets  '開いたブック内のシート数分のループ
            If sh.Name = "Formula" Then GoTo pass
            'シート名の設定保存列を検索する
            c = Application.WorksheetFunction.Match(sh.Name, .Rows(1), 0)
            n = .Cells(Rows.Count, c).End(xlUp).Row '設定の最終行
            For r = 3 To n          '設定数分のループ
                rng = .Cells(r, c)  'アドレスを文字列変数に入れる
                sh.Range(rng).Formula = .Cells(r, c + 1).Formula '数式をセット
            Next
pass:
        Next
    End With
    tgwb.Close (False)  '開いたブックを閉じる
    Set tgwb = Nothing  'オブジェクト解放
    Set wb = Nothing
    Set sh = Nothing
    With Application
        .Calculation = xlCalculationAutomatic '計算を自動に
        .ScreenUpdating = True                '画面描画開始
    End With
    MsgBox "計算式の再設定（書き込み）を完了しました！"
End Sub

Option Explicit
'取得実行処理呼び出し
Private Sub CommandButton1_Click()
    Call GetFormulas
End Sub
'数式再設定処理呼び出し
Private Sub CommandButton2_Click()
    Call SetFormulas
End Sub
'コマンドボタンの挙動制御
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim WinTop As Long
    Dim WinLeft As Long
    '表示されている画面の位置を変数にセット
    WinTop = ActiveWindow.VisibleRange.Top
    WinLeft = ActiveWindow.VisibleRange.Left
    'コマンドボタンの位置を表示画面からの位置に設定
    CommandButton1.Top = WinTop + 70
    CommandButton2.Top = WinTop + 140
    CommandButton1.Left = WinLeft + 165
    CommandButton2.Left = WinLeft + 165
End Sub