ExcelVBA TypeName関数 変数の型名を返します

'■TypeName関数サンプル１(データ)
Sub TypeName_Sample01()
  Dim var As Variant  'Variant型変数を用意
  'Variant型変数Varが初期化されていない状態
  Debug.Print TypeName(var)   'Empty
  
  var = CByte(12)
  Debug.Print TypeName(var)   'Byte
  
  var = 12
  Debug.Print TypeName(var)   'Integer
  
  var = 1234567890
  Debug.Print TypeName(var)   'Long
  
  var = CSng(3.45)
  Debug.Print TypeName(var)   'Single
  
  var = 678901234567#
  Debug.Print TypeName(var)   'Double
  
  var = CCur(1234.5678)
  Debug.Print TypeName(var)   'Currency
  
  var = CDec(12345.67)
  Debug.Print TypeName(var)   'Decimal
  
  var = Now
  Debug.Print TypeName(var)   'Date
  
  var = "1234.5678"
  Debug.Print TypeName(var)   'String
  
  var = True
  Debug.Print TypeName(var)   'Boolean
  
  var = CVErr(5)
  Debug.Print TypeName(var)   'Error
  
  var = Null  'Variant型変数VarにNullを明示的に代入
  Debug.Print TypeName(var)   'Null
End Sub

'■TypeName関数サンプル２(オブジェクト)
Sub TypeName_Sample02()
  Dim obj As Object 'オブジェクト変数を用意
  '変数が初期化前に型を調べてみる
  Debug.Print TypeName(obj)   'Nothing
  
  Set obj = ActiveCell  '初期化
  Debug.Print TypeName(obj)   'Range
  Set obj = Nothing     '解放
  
  Set obj = ActiveSheet
  Debug.Print TypeName(obj)   'Worksheet
  Set obj = Nothing
  
  Set obj = Worksheets
  Debug.Print TypeName(obj)   'Sheets
  Set obj = Nothing
  
  Set obj = ThisWorkbook
  Debug.Print TypeName(obj)   'Workbook
  Set obj = Nothing
  
  Set obj = Workbooks
  Debug.Print TypeName(obj)   'Workbooks
  Set obj = Nothing
  
  Set obj = Excel.Application
  Debug.Print TypeName(obj)   'Application
  Set obj = Nothing
  
  Set obj = CreateObject("Scripting.Dictionary")
  Debug.Print TypeName(obj)   'Dictionary
  Set obj = Nothing
  
  Set obj = CreateObject("Scripting.FileSystemObject")
  Debug.Print TypeName(obj)   'FileSystemObject
  Set obj = Nothing
End Sub

'■TypeName関数サンプル３(配列)
Sub TypeName_Sample03()
  'Variantの配列
  Dim var As Variant
  var = Array(0, "1", 2)
  Debug.Print TypeName(var)     'Variant()
  Debug.Print TypeName(var(0))  'Integer
  Debug.Print TypeName(var(1))  'String
  
  'Integerの配列
  Dim i(10) As Integer
  Debug.Print TypeName(i)       'Integer()
  
  'Stringの配列
  Dim str(10) As String
  str(0) = "あ"
  Debug.Print TypeName(str)     'String()
  Debug.Print TypeName(str(0))  'String
End Sub